리습 강좌 - POPUP_LIST 박스 , 다이얼로그 연동관계 예제
| 본 강좌는 아키오피스(김희태)에 의해 만들어 졌으며 어떠한 웹상에 아키오피스(김희태)의 동의없이 올리는 것을 허락하지 않습니다. |
POPUP_LIST 박스의 작동방식및,다이얼로그
간에 연동관계 예제 입니다.
| ||
|
| ||
이 예제를 실행해보려면 파일을 다운받아 캐드의 support 디렉토리에
| ||
(defun c:exdialog (/ vimage vlist id listdata-product1 listdata-product2
listdata-product3 ok-actio ok )
(defun vimage (a key / )
(start_image key)
(fill_image 0 0 (dimx_tile key) (dimy_tile key) -2)
(slide_image 0 0 (dimx_tile key) (dimy_tile key) a)
(end_image)
)
(defun vlist (a key / )
(start_list key)
(mapcar 'add_list a)
(end_list)
)
(defun ok-action()
(alert (strcat "\n선택하신 제품은 \""
(nth (atoi (get_tile "plist1")) (cadr ok))
"\" 과 \""
(nth (atoi (get_tile "plist2")) (caddr ok))
"\" 입니다! 프로그램 끝~~!"
)
)
)
(setq listdata-product1 '("제품 1 입니다." ("김" "미역" "다시마" "조개" "오징어" "쭈꾸미")("배" "사과" "귤" "오랜지")))
(setq listdata-product2 '("제품 2 입니다." ("나사" "볼트" "드라이버")("선반" "절삭" "기타등등")))
(setq listdata-product3 '("제품 3 입니다." ("1" "2" "3" "4" "5" "6" "7" "8")("d" "c" "b" "a")))
(setq id (load_dialog "exdialog.dcl"))
(new_dialog "exdialog" id)
(vimage "ACAD(TRANS)" "image1")
(vimage "ACAD(TRIANG)" "image2")
(vimage "ACAD(STEEL)" "image3")
(action_tile "image1" "(done_dialog 1)")
(action_tile "image2" "(done_dialog 2)")
(action_tile "image3" "(done_dialog 3)")
(action_tile "accept" "(done_dialog 0)")
(action_tile "cancel" "(done_dialog 0)")
(setq ok (start_dialog))
(if (< 0 ok)
(progn
(new_dialog "popup_dialog" id)
(setq ok (eval (read (strcat "listdata-product" (itoa ok)))))
(set_tile "text" (car ok))
(vlist (cadr ok) "plist1")
(vlist (caddr ok) "plist2")
(action_tile "accept" "(ok-action)(done_dialog)")
(action_tile "cancel" "(done_dialog)")
(start_dialog)
)
)
(unload_dialog id)
(princ)
)
>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> DCL 정의 부분 <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
exdialog : dialog { label = "리스트 - 이미지 예제 다이얼로그";
:row {
:icon_image {key = "image1";width = 15;fixed_width = true;fixed_height = true; aspect_ratio = 1; }
:icon_image {key = "image2";width = 15;fixed_width = true;fixed_height = true; aspect_ratio = 1; }
:icon_image {key = "image3";width = 15;fixed_width = true;fixed_height = true; aspect_ratio = 1; }
}
ok_cancel;
}
popup_dialog : dialog { label = "선택하시오~!";
:text { key = "text";}
:popup_list { key= "plist1"; }
:popup_list { key = "plist2";}
ok_cancel;
}
(defun c:exdialog (/ vimage vlist id listdata-product1 listdata-product2
listdata-product3 ok-actio ok )
;; image 타리에 이미지(슬라이드)를 출력하는 함수다.
(defun vimage (a key / )
(start_image key)
(fill_image 0 0 (dimx_tile key) (dimy_tile key) -2)
(slide_image 0 0 (dimx_tile key) (dimy_tile key) a)
(end_image)
)
;; popup_list 또는 list_box 에 리스트를 출력하는 함수다.
(defun vlist (a key / )
(start_list key)
(mapcar 'add_list a)
(end_list)
)
;; 사용자가 최종선택을 했을때 해당 리스트박스에 해당하는 값을 출력하는 함수다.
(defun ok-action()
(alert (strcat "\n선택하신 제품은 \""
;; popup_list 는 단지 몇번째만을 리턴한다. 그러므로
;; 데이타리스트에서 해당 번째의 데이타를 읽어온다.
(nth (atoi (get_tile "plist1")) (cadr ok))
"\" 과 \""
(nth (atoi (get_tile "plist2")) (caddr ok))
"\" 입니다! 프로그램 끝~~!"
)
)
)
;; 각각의 데이타이다.
(setq listdata-product1 '("제품 1 입니다." ("김" "미역" "다시마" "조개" "오징어" "쭈꾸미")("배" "사과" "귤" "오랜지")))
(setq listdata-product2 '("제품 2 입니다." ("나사" "볼트" "드라이버")("선반" "절삭" "기타등등")))
(setq listdata-product3 '("제품 3 입니다." ("1" "2" "3" "4" "5" "6" "7" "8")("d" "c" "b" "a")))
(setq id (load_dialog "exdialog.dcl"))
(new_dialog "exdialog" id)
(vimage "ACAD(TRANS)" "image1")
(vimage "ACAD(TRIANG)" "image2")
(vimage "ACAD(STEEL)" "image3")
;; 각각의 이미지를 클릭하면 ok 변수에 해당리턴되는 값이 입력된다.
(action_tile "image1" "(done_dialog 1)")
(action_tile "image2" "(done_dialog 2)")
(action_tile "image3" "(done_dialog 3)")
(action_tile "accept" "(done_dialog 0)")
(action_tile "cancel" "(done_dialog 0)")
;; 리턴되는 값을 ok 변수에 저장한다.
(setq ok (start_dialog))
;; 이미지를 선택했다면....
(if (< 0 ok)
(progn
;; 두번째 다이얼로그 "popup_dialog" 를 불러온다.
(new_dialog "popup_dialog" id)
;; ok 변수에 이전 다이얼로그에 해당하는 데이타를 입력한다.
(setq ok (eval (read (strcat "listdata-product" (itoa ok)))))
;; 타이들을 출력하고 리스트박스(popup_list)에 값을 출력한다.
(set_tile "text" (car ok))
(vlist (cadr ok) "plist1")
(vlist (caddr ok) "plist2")
;; 사용자가 "확인" 을 누루면 선택된 아이템을 출력한다.
(action_tile "accept" "(ok-action)(done_dialog)")
(action_tile "cancel" "(done_dialog)")
(start_dialog)
)
)
(unload_dialog id)
(princ)
)