리습 강좌 - 폴리라인을 따라 일정한 간격으로 번호 매기는 예제.

본 강좌는 아키오피스(김희태)에 의해 만들어 졌으며
어떠한 웹상에 아키오피스(김희태)의 동의없이 올리는 것을 허락하지 않습니다.

 

폴리라인선위에 일정한 간격으로 폴리라인과 평행하게 번호를 매기는 예제입니다.


실행명:p-divide-t

코드


(defun c:p-divide-t ( / pn le first x el n ssp th rtd)
  (defun rtd (a)(/ (* a 180.0) pi))
  (setq pn (car (entsel "\n폴리라인을 선택하세요.")))
  (setq le (getreal "\n거리값을 입력하세요 :"))
  (setq th (getreal "\n문자의 크기를 입력하세요 :"))
  (setq first (car (mapcar 'cdr (GetPolyVtx (entget pn)))))
  (setq el (entlast)  n 0)
  (command "measure" (list pn first) le)
  (if (not (equal el (entlast)))
    (progn
      (while (setq ex (entnext el))
        (setq ssp (append ssp (list (cdr (assoc 10 (entget ex))))) el ex)
      )
      (mapcar '(lambda (x)
                 (command "text" "j" "c" x th (rtd (angle first x)) (itoa n))
                 (setq n (1+ n) first x)
               )
              ssp
      )
    )
  )
  (princ)
)
설명

(defun c:p-divide-t ( / pn le first x el n ssp th rtd)
  ;; 라디안 각도 값을 디그리 각도로 변환함수
  (defun rtd (a)(/ (* a 180.0) pi))
  ;; 폴리라인,거리값,문자 크기를 입력 받는다.
  (setq pn (car (entsel "\n폴리라인을 선택하세요.")))
  (setq le (getreal "\n거리값을 입력하세요 :"))
  (setq th (getreal "\n문자의 크기를 입력하세요 :"))
  ;; 폴리라인의 첫점을 getpolyvtx 함수를 이용하여 알아낸다.
  (setq first (car (mapcar 'cdr (GetPolyVtx (entget pn)))))
  (setq el (entlast)  n 0)
  ;; measure 명령으로 폴리라인상에 일정한 간격으로 포인트를 생성한다.
  (command "measure" (list pn first) le)
  (if (not (equal el (entlast)))
    (progn
      ;; 포인트들의 위치점을 저장한다.
      (while (setq ex (entnext el))
        (setq ssp (append ssp (list (cdr (assoc 10 (entget ex))))) el ex)
      )
      ;; 위치점에 각각의 문자를 mapcar 함수를 이용하여 생성한다. 
      ;; 문자의 각도는 이전의 위치점과 현재의 위치점으로 각도를 계산한다. 
      (mapcar '(lambda (x)
                 (command "text" "j" "c" x th (rtd (angle first x)) (itoa n))
                 (setq n (1+ n) first x)
               )
              ssp
      )
    )
  )
  (princ)
)