리습 강좌 - Activex 함수를 이용한 햇치의 고립영역 탐지유형 적용 및 이해.

본 강좌는 아키오피스(김희태)에 의해 만들어 졌으며
어떠한 웹상에 아키오피스(김희태)의 동의없이 올리는 것을 허락하지 않습니다.

 

고립영역 탐지 유형에 따라 햇치의 스타일이 바뀜니다.
이런 고립영역 탐지 유형을 리습에서 어떻게 구현하는지 보시기 바랍니다.
이 예제는 단지 이해를 목적으로 만든 리습입니다.

리습 공부에 도움 되시길....

아래처럼 햇치할 영역으로 포인트를 십자마크위치에서 클릭 했을때

(hatch-test  point  햇치채움타입번호)
0 = acHatchStylenormal => 내외부 채움 방식
1 = acHatchStyleouter => 외부만 채움 방식
2 = acHatchStyleignore => 전체 채움 방식



(hatch-test (getpoint) 2) =>전체 채움 타입


(hatch-test (getpoint) 1) => 외곽만 채움 타입
아래그림처럼 되야 하지만 전체 채움이 됨.
vba의 똑같은 예제도 해보았으나 마찮가지로 전체채움이 됨.
activex 의 버그 같음!!


(hatch-test (getpoint) 0) => 내외부 채움 타입

코드


  (defun hatch-test (point HatchStyle / ex lapp sa saout acadobject acaddocument mspace n myhatch)
    (setq ex (entlast))
    (command "boundary" point "")
    (if (not (equal ex (entlast)))
      (progn
        (while (setq ex (entnext ex))
          (setq lapp (cons ex lapp))
        )
        (vl-load-com)
        (setq acadObject   (vlax-get-acad-object))
        (setq acadDocument (vla-get-ActiveDocument acadObject))
        (setq mSpace       (vla-get-ModelSpace acadDocument))
        (setq myhatch (vlax-invoke-method mspace 'Addhatch 0 "ansi31" :vlax-false))
        (vla-put-patternscale myhatch 1)
       	(setq sa (vlax-make-safearray vlax-vbObject '(0 . 0) ))
        (setq saout (vlax-make-safearray vlax-vbObject '(0 . 0)))
        (vlax-safearray-put-element saout 0 (vlax-ename->vla-object (nth 0 lapp)))
        (vla-appendouterloop myhatch saout)
        (setq n 1)
        (repeat (1- (length lapp))
          (vlax-safearray-put-element sa 0 (vlax-ename->vla-object (nth n lapp)))
          (vla-AppendinnerLoop myhatch sa)
          (setq n (1+ n))
        )  
        (vla-put-hatchstyle myhatch HatchStyle);acHatchStylenormal
        (vla-Evaluate myhatch)
        (vla-regen acadDocument acActiveViewport)
        (mapcar 'entdel lapp)
      )
    )
    (princ)
  )
설명

  (defun hatch-test (point HatchStyle / ex lapp sa saout acadobject acaddocument mspace n myhatch)
    (setq ex (entlast))
    ;; 영역들을 생성한다.
    (command "boundary" point "")
    (if (not (equal ex (entlast)))
      (progn
        ;; 영역들을 모은다.
        (while (setq ex (entnext ex))
          (setq lapp (cons ex lapp))
        )
        (vl-load-com)
        (setq acadObject   (vlax-get-acad-object))
        (setq acadDocument (vla-get-ActiveDocument acadObject))
        (setq mSpace       (vla-get-ModelSpace acadDocument))
        ;; 햇치 오브잭트를 만든다.
        (setq myhatch (vlax-invoke-method mspace 'Addhatch 0 "ansi31" :vlax-false))
        ;; 패던 scale 를 정한다.
        (vla-put-patternscale myhatch 1)
        ;; 내부루프(내부영역)를 저장할 변수를 만든다.
       	(setq sa (vlax-make-safearray vlax-vbObject '(0 . 0) ))
        ;; 외부루프(외부영역)를 저장할 변수를 만든다.
        (setq saout (vlax-make-safearray vlax-vbObject '(0 . 0)))
        ;; 가장 바깥의 루프를 appendouterloop 함수로 햇치 오브잭트에 추가한다.
        (vlax-safearray-put-element saout 0 (vlax-ename->vla-object (nth 0 lapp)))
        (vla-appendouterloop myhatch saout)
        ;; 나머지 내부루프를 AppendinnerLoop 함수로 각각 햇치 오브잭트에 추가 한다.
        (setq n 1)
        (repeat (1- (length lapp))
          (vlax-safearray-put-element sa 0 (vlax-ename->vla-object (nth n lapp)))
          (vla-AppendinnerLoop myhatch sa)
          (setq n (1+ n))
        )  
        ;; 햇치 style 를 적용한다.
        ;; 0 = acHatchStylenormal => 내외부 채움 방식
        ;; 1 = acHatchStyleouter  => 외부만 채움 방식
        ;; 2 = acHatchStyleignore => 전체 채움 방식
        (vla-put-hatchstyle myhatch HatchStyle)
        ;; 햇치를 평가하여 갱신한다.
        (vla-Evaluate myhatch)
        ;; regen 으로 햇치를 출력한다.
        (vla-regen acadDocument acActiveViewport)
        ;; 생성된 영역들을 삭제한다.
        (mapcar 'entdel lapp)
      )
    )
    (princ)
  )