리습 강좌 - PLINE 정점들의 방향 체크 함수.

본 강좌는 아키오피스(김희태)에 의해 만들어 졌으며 어떠한 웹이나
출판물에 아키오피스(김희태)의 동의없이 올리는 것을 허락하지 않습니다.

 


닫힌 pline 의 정점들의 순서가 시계방향인지 시계반대 방향인지 체크합니다.
pline 의 정점은 최소 3개 이상이어야 합니다.
시계방향이면 "right" , 시계반대방향이면 "left" 를 리턴합니다.


(pl-l-r-chk pline-ename pline의 내부점)

(pl-l-r-chk (car (entsel)) (getpoint)) => 1번의 경우 "right" 리턴.

(pl-l-r-chk (car (entsel)) (getpoint)) => 2번의 경우 "left" 리턴.

코드


  (defun GetPolyVtx(EntList / VtxList AA X)
    (setq VtxList '())
    (IF (= "LWPOLYLINE" (CDR (ASSOC 0 EntList))) 
     (mapcar '(lambda (x) (if (= 10 (car x)) (setq VtxList (append VtxList (list (cdr x))) ) ) ) EntList)
     (PROGN
      (SETQ AA (ENTGET(ENTNEXT (CDR (ASSOC -1 EntList)))))
      (WHILE (/= "SEQEND" (CDR (ASSOC 0 AA)))
        (setq VtxList (append VtxList (list (cdr (ASSOC 10 AA)))))
        (SETQ AA (ENTGET(ENTNEXT (CDR (ASSOC -1 AA)))))
      )
    ));IF
    VtxList
  )

  (defun pl-l-r-chk (pn poin / plist rtd ang+ ang-)
    (defun rtd (a)(/ (* a 180.0) pi))
    (setq plist (getpolyvtx (entget pn)) ang+ 0 ang- 0)
    (setq plist (mapcar '(lambda (x) (rtd (angle poin x))) plist))
    (mapcar '(lambda (x y)
               (cond
                 ((and (< 180 (abs (- x y))) (< 180 x) (> 180 y)) (setq ang+ (+ ang+ (- 360 x) y)))
                 ((and (< 180 (abs (- x y))) (> 180  x) (< 180 y)) (setq ang- (+ ang- x (- 360 Y))))
                 ((< x y) (setq ang+ (+ ang+ (- y x))))
                 ((> x y) (setq ang- (+ ang- (- x y))))
               )
             )	 
            plist (cdr (append plist (list (car plist))))
    )
    (if (< ang+ ang-) "right" "left")
  )
설명

  (defun pl-l-r-chk (pn poin / plist rtd ang+ ang-)
    ;; 라디안각도 값을 디그리각도로 변환하는 함수다.
    (defun rtd (a)(/ (* a 180.0) pi))
    ;; 정점들을 추출한다.
    (setq plist (getpolyvtx (entget pn)) ang+ 0 ang- 0)
    ;; pline 내부점과 정점과의 각도리스트를 만든다.
    (setq plist (mapcar '(lambda (x) (rtd (angle poin x))) plist))
    ;; 각도가 증가하면 각도를 ang+ 변수에 , 감소하면 ang- 변수에 변화각도를 합한다.
    (mapcar '(lambda (x y)
               (cond
                 ;; 각도의 특성상 두 각도가 0 도를 끼고 있을때의 계산방법이다.
                 ((and (< 180 (abs (- x y))) (< 180 x) (> 180 y)) (setq ang+ (+ ang+ (- 360 x) y)))
                 ((and (< 180 (abs (- x y))) (> 180  x) (< 180 y)) (setq ang- (+ ang- x (- 360 Y))))
                 ((< x y) (setq ang+ (+ ang+ (- y x))))
                 ((> x y) (setq ang- (+ ang- (- x y))))
               )
             )	 
            plist (cdr (append plist (list (car plist))))
    )
    ;; 계산된 결과에 따라 "right" 또는 "left" 를 출력한다.
    (if (< ang+ ang-) "right" "left")
  )