리습 강좌 - dll 함수이용하기-난수발생,한영키전환,파일찾기.

본 강좌는 아키오피스(김희태)에 의해 만들어 졌으며 어떠한 웹이나
출판물에 아키오피스(김희태)의 동의없이 올리는 것을 허락하지 않습니다.

 


이 함수는 dll 을 이용하는 함수로

dll 의 내부함수로 값을 보내고 결과값을 리턴 받는 형식입니다.

vl-random 은 두수사이에 난수를 발생하여 리턴합니다.

vl-IMEmode 은 한영키를 t 이면 영문으로 전환하고 nil 이면 한글로 전환합니다.

vl-findfiles 은 특정 디렉토리의 하부디렉토리까지

포함하여 파일(와일드카드 포함)을 찾아 리턴합니다.

이 함수들을 실행하려면 우선 해당 DLL 을 다운받아 시스템에 설치해야 합니다.


설치하는 방법은 아래내용을참조 하세요.


(vl-random 10 1) => 10 과 1 사이의 난수를 실수로 리턴한다.

(vl-imemode t) => t 이면 한영키를 영문으로 nil 이면 한글로 전환한다.

(vl-findfiles 경로 파일명) => 하부디렉토리까지 검색하여 찾은 경로를 리스트로 리턴한다.

(vl-findfiles "c:\\program files" "ac*.exe")

=>("C:/Program Files/ACAD2000/acad.exe"
"C:/Program Files/ACDSee32/ACDSee32.exe"
"C:/Program Files/AutoCAD LT 2000/aclt.exe"
"C:/Program Files/AutoCAD R14/acad.exe"
"C:/Program Files/Adobe/Acrobat 4.0/Reader/AcroRd32.exe"
"C:/Program Files/Microsoft Visual Studio/Vfp98/Distrib.src/Setup/ACMSETUP.EXE")




DLL 시스템에 설치하는 방법!!

캐드를 실행하기 전에 윈도우의 시작 -> 실행 을 클릭한다.



아래 그래그림과 같이 regsvr32 로 DLL 을 시스템이 등록한다.
경로는 dll 이 위치한 곳으로 하면 된다.



캐드를 실행하고 이 함수를 실행하면 된다. dll 등록은 한번만 하면 된다.

코드


  (defun vl-random (a b / acad srve reval)
    (cond
      ((= a b) nil)
      ((not (or (= 'INT (type a)) (= 'REAL (type a)))) nil)
      ((not (or (= 'INT (type b)) (= 'REAL (type b)))) nil)
      (t
       (vl-load-com)
       (setq acad (vlax-get-acad-object))
       (setq srve (vlax-invoke acad "getinterfaceobject" "rnd_ff_ime.clarandom"))
       (setq reval (vlax-invoke srve "vl_random" a b))
       (if (= 0 reval) nil reval)
      )
    )  
  )

  (defun vl-IMEmode (a / acad srve reval)
    (vl-load-com)
    (setq acad (vlax-get-acad-object))
    (setq srve (vlax-invoke acad "getinterfaceobject" "rnd_ff_ime.clarandom"))
    (if a
      (setq reval (vlax-invoke srve "vl_IMEmode" 1))
      (setq reval (vlax-invoke srve "vl_IMEmode" 0))
    )  
  )

  (defun vl-findfiles (a b / acad srve reval)
    (cond
      ((not (= 'STR (type a))) nil)
      ((not (= 'STR (type b))) nil)
      ((not (vl-directory-files a nil -1)) nil)
      (t
       (vl-load-com)
       (setq acad (vlax-get-acad-object))
       (setq srve (vlax-invoke acad "getinterfaceobject" "rnd_ff_ime.clarandom"))
       (setq reval (vlax-invoke srve "vl_findfile" a b))
       (if (= 0 reval) nil reval)
      )
    )  
  )
설명

  ;; 난수를 발생하는 함수다.  a 와 b 사이에 난수를 발생하여 실수를 리턴한다.
  (defun vl-random (a b / acad srve reval)
    (cond
      ;; a b 가 같거나 숫자가 아니라면 끝낸다.
      ((= a b) nil)
      ((not (or (= 'INT (type a)) (= 'REAL (type a)))) nil)
      ((not (or (= 'INT (type b)) (= 'REAL (type b)))) nil)
      (t
       (vl-load-com)
       (setq acad (vlax-get-acad-object))
       ;; dll 함수를 가져와 
       (setq srve (vlax-invoke acad "getinterfaceobject" "rnd_ff_ime.clarandom"))
       ;; dll 의 내부함수 vl_random 을 실행하여 결과같을 리턴받는다.
       (setq reval (vlax-invoke srve "vl_random" a b))
       ;; 결과값이 있다면 값을 리턴한다.
       (if (= 0 reval) nil reval)
      )
    )  
  )

  ;; 한,영키를 전환 함수다. 
  (defun vl-IMEmode (a / acad srve reval)
    (vl-load-com)
    (setq acad (vlax-get-acad-object))
    ;; dll 함수를 가져와 
    (setq srve (vlax-invoke acad "getinterfaceobject" "rnd_ff_ime.clarandom"))
    ;; 내부함수 vl_IMEmode 를 실행하여 a 가 t 이면 영문으로 전환하고 nil 이면 한글로 전환한다.
    (if a
      (setq reval (vlax-invoke srve "vl_IMEmode" 1))
      (setq reval (vlax-invoke srve "vl_IMEmode" 0))
    )  
  )

  ;; 파일을 찾는 함수다. a 는 찾을 디렉토리, b 는 찾을 파일이름(와일드 카드포함)
  (defun vl-findfiles (a b / acad srve reval)
    (cond
      ;;  a,b 가 문자가 아니거나 a 디렉토리가 존재하지 않으면 끝낸다.
      ((not (= 'STR (type a))) nil)
      ((not (= 'STR (type b))) nil)
      ((not (vl-directory-files a nil -1)) nil)
      (t
       (vl-load-com)
       (setq acad (vlax-get-acad-object))
       ;; dll 함수를 가져와
       (setq srve (vlax-invoke acad "getinterfaceobject" "rnd_ff_ime.clarandom"))
       ;; 내부함수 vl_findfile 를 실행하여 결과를 리턴받는다. 결과가 없다면 nil
       (setq reval (vlax-invoke srve "vl_findfile" a b))
       (if (= 0 reval) nil reval)
      )
    )  
  )