리습 강좌 - Pline 에 아크를 생성하는 함수.

본 강좌는 아키오피스(김희태)에 의해 만들어 졌으며 어떠한 웹이나
출판물에 아키오피스(김희태)의 동의없이 올리는 것을 허락하지 않습니다.

 

pline 에 아크를 생성할때 하나의 반지름 값에 대해 블지 값은 4 개가 존재합니다.
아래 그림과 같이 두점 p1,p2 사이에 반지름 100 인 원은 두개 존재할수 있습니다.



그래서 이함수는 사용자가 의도하는 조건에 따라 아크를 생성할수 있는 함수 입니다.
각 조건에 대해서는 아래를 참조하세요.


(vl-setbulge pline_Ename intNth r s+- sel)

pline_Ename : pline entName
intNth : 아크가 시작되는 번호 . pline 의 첫번째점이 0 번이고 두번째 점이 1 번이다.
s+- : 가 '- 이면 첫번째 점에서 두번째 점으로 시계 방향 그려진다.
s+- : 가 '+ 이면 첫번째 점에서 두번째 점으로 시계반대 방향 그려진다.
r : 반지름값
sel : 이 T 이면 큰 블지값을 취하고
sel : 이 nil 이면 작은 블지값을 취한다.

첫번째 점에서 두번째 점으로 시계방향으로 그려질 경우.



첫번째 점에서 두번째 점으로 시계반대방향으로 그려질 경우.
코드
  
  (defun vl-setbulge (objEname intNth r s+- sel / bulgeFactor Pvtx bulgeFact)

    (defun bulgeFactor (pt1 pt2 r s+- sel / c h h- bulge)
      (setq
         c (/ (distance pt1 pt2) 2.0)
         h (+ r (sqrt (- (expt r 2) (expt c 2))))
         h- (- r (sqrt (- (expt r 2) (expt c 2))))
         bulge (/ ((eval s+-) (if sel h h-)) c)
      )
    )

    (setq Pvtx (GetPolyVtx (entget objEname)))
    (cond
      ((or (< intNth 0) (> intNth (- (length pvtx) 2))) nil)
      ((> r (/ (distance (nth intNth Pvtx) (nth (1+ intNth) Pvtx)) 2.0))
         (setq bulgeFact (bulgeFactor (nth intNth Pvtx) (nth (1+ intNth) Pvtx) r s+- sel))
         (vla-setBulge (vlax-Ename->vla-Object objEname) intNth bulgeFact)
      )
    )
  )
설명

  (defun vl-setbulge (objEname intNth r s+- sel / bulgeFactor Pvtx bulgeFact)

    ;; 주어진 조건에 따라 블지 값을 리턴하는 함수.
    (defun bulgeFactor (pt1 pt2 r s+- sel / c h h- bulge)
      (setq
         c (/ (distance pt1 pt2) 2.0)
         h (+ r (sqrt (- (expt r 2) (expt c 2))))
         h- (- r (sqrt (- (expt r 2) (expt c 2))))
         bulge (/ ((eval s+-) (if sel h h-)) c)
      )
    )

    ;; 피라인의 정점들을 리턴한다.
    (setq Pvtx (GetPolyVtx (entget objEname)))
    (cond
      ;; 아크생성할 시작점(intNth)이 0 보다 작거나 최대정점수보다 크다면 종료한다.
      ((or (< intNth 0) (> intNth (- (length pvtx) 2))) nil)
      ;; 지름보다 두점의 거리값이 큰경우는 존재하지 않기 때문에
      ;; 아크를 생성할 두점의 거리값이 아크의 지름보다 작을경우에만 아크를 생성한다.
      ((> r (/ (distance (nth intNth Pvtx) (nth (1+ intNth) Pvtx)) 2.0))
         ;; 각 조건에 의해 블지값을 얻는다.
         (setq bulgeFact (bulgeFactor (nth intNth Pvtx) (nth (1+ intNth) Pvtx) r s+- sel))
         ;; activex 함수를 이용해 pline 해당 지점에 아크를 생성한다.
         (vla-setBulge (vlax-Ename->vla-Object objEname) intNth bulgeFact)
      )
    )
  )